
REM ## PARAMETERABFRAGE ##
if ".%1" == "." goto flschpar
if ".%1" == "./?" goto hilfe
if ".%1" == "./E" goto machdbd
if ".%1" == "./e" goto machdbd
if ".%1" == "./A" goto auto
if ".%1" == "./a" goto auto
if ".%1" == "./V" goto vers
if ".%1" == "./v" goto vers
if ".%2" == "./P" goto istp
if ".%2" == "./p" goto istp
if ".%2" == "./D" goto istd
if ".%2" == "./d" goto istd
if ".%2" == "." goto suchen1
if not ".%2" == "." goto flschpar
:istp
if not ".%3" == "." goto flschpar
goto suchen2
:istd
if ".%3" == "." goto flschpar
if not ".%4" == "." goto flschpar
goto suchen3

REM ## HILFE ##
:hilfe
echo Such speichert Verzeichniseintraege von Festplattenpartitionen
echo in einer Datei und vereinfacht das Durchsuchen dieser Datei.
echo .
echo "SUCH /A | /E | /V | Zeichenfolge [/D Datei | /P]"
echo .
echo "/A" Automatikmodus fuer Datenbankerstellung bei jedem 10. System-Start.
echo "/D" Ausgabe der Suchanfrage wird in Datei umgeleitet.
echo "/E" Erstellt die zur Suche benoetigte Datenbankdatei sofort.
echo "/P" Ausgabe der Suchanfrage erfolgt seitenweise auf dem Bildschirm.
echo "/V" gibt die Versionsnummer aus.
echo Zeichenfolge = beliebige Zeichen von Pfad-/Dateinamen,
echo                nach denen gesucht werden soll.
echo Datei = beliebiger Name von Datei (auch mit Pfad),
echo         in die die Ausgabe gespeichert werden soll.
goto ende

REM ## VERSION ##
:vers
echo InKaSuch Version 1.4
goto ende

REM ## AUTOMATIKMODUS ##
:auto
if exist %datdir%\Such.009 ren %datdir%\Such.009 Such.000
if exist %datdir%\Such.008 ren %datdir%\Such.008 Such.009
if exist %datdir%\Such.007 ren %datdir%\Such.007 Such.008
if exist %datdir%\Such.006 ren %datdir%\Such.006 Such.007
if exist %datdir%\Such.005 ren %datdir%\Such.005 Such.006
if exist %datdir%\Such.004 ren %datdir%\Such.004 Such.005
if exist %datdir%\Such.003 ren %datdir%\Such.003 Such.004
if exist %datdir%\Such.002 ren %datdir%\Such.002 Such.003
if exist %datdir%\Such.001 ren %datdir%\Such.001 Such.002
if exist %datdir%\Such.000 goto machdbd

REM ## DATENBANKDATEI ANLEGEN UND GGF. ZAEHLER ZURUECKSETZEN     ##
:machdbd
REM ###############################################################
REM ##                      H I N W E I S :                      ##
REM ## Nach der Installation wird nur  Laufwerk  C:  durchsucht. ##
REM ## Zum Durchsuchen weiterer Laufwerke das  "REM "  am Anfang ##
REM ## der jeweiligen Zeile entfernen, ggf. weitere gleichartige ##
REM ## Zeilen  mit   weiteren   Laufwerksbuchstaben   erstellen. ##
REM ###############################################################
dir /b /s /-p C:\ > %datdir%\Such.dbd
REM dir /b /s /-p D:\ >> %datdir%\Such.dbd
REM dir /b /s /-p E:\ >> %datdir%\Such.dbd
REM dir /b /s /-p F:\ >> %datdir%\Such.dbd
REM dir /b /s /-p G:\ >> %datdir%\Such.dbd
REM dir /b /s /-p H:\ >> %datdir%\Such.dbd
REM dir /b /s /-p I:\ >> %datdir%\Such.dbd
REM dir /b /s /-p J:\ >> %datdir%\Such.dbd
REM dir /b /s /-p K:\ >> %datdir%\Such.dbd
REM ###############################################################
REM ## Die Zeile mit dem ersten zu durchsuchenden Laufwerk darf  ##
REM ## nur   eine   spitze   Klammer   nach   rechs   enthalten. ##
REM ## alle weiteren Zeilen  mit  zu  durchsuchenden  Laufwerken ##
REM ## muessen  zwei  spitze  Klammern  nach  rechs   enthalten. ##
REM ###############################################################

if exist %datdir%\Such.000 ren %datdir%\Such.000 Such.001
goto ende

REM ## DATEI SUCHEN UND ANZEIGEN ##
:suchen1
type %datdir%\Such.dbd | find /i "%1"
goto ende

REM ## DATEI SUCHEN UND SEITENWEISE ANZEIGEN ##
:suchen2
type %datdir%\Such.dbd | find /i "%1" | more
goto ende

REM ## DATEI SUCHEN UND AUSGABE IN DATEI UMLEITEN ##
:suchen3
echo Ergebnis der Suche:> %3
type %datdir%\Such.dbd | find /i "%1">> %3
goto ende

REM ## FALSCHE PARAMETERANGABE
:flschpar
echo Fehler - Falsche Parameterangabe!
echo "such /? " gibt Hilfe.
goto ende

:ende
set datdir=