@echo off
REM NAME: IKSuchun.bat (aus dem Paket InKaSuch)
REM AUTOR: Ingo Kaesmann, http://www.ingokaesmann.de

REM ## PARAMETERABFRAGE ##
if ".%1" == "./?" goto hilfe
if ".%1" == "./U" goto start
if ".%1" == "./u" goto start
if not ".%1" == "." goto flschpar
goto:fragunin

REM ## SICHERHEITSABFRAGE ##
:fragunin
echo Soll InKaSuch deinstalliert werden?
echo Wenn nicht, [Strg][C] druecken und Abfrage mit Ja bestaetigen.
echo Wenn eine andere Taste gedrueckt wird, wird IKSuch deinstalliert.
pause > nul
goto vardef

REM ## HILFE ##
:hilfe
echo Deinstalliert InKaSuch Version 1.4
echo .
echo "IKSUCHUN [/U]"
echo .
echo "/U" Ohne Bestaetigung.
goto ende

REM ## START MIT VARIABLENDEFINITION UND SYSTEMSCAN ##
:start
set param1=u
:vardef
set instdir1=%windir%\..\"Program Files"
set instdir2=InKaSoft
set instdir3=Such

echo Deinstalliere InKaSuch
if exist %windir%\win.ini goto syswin
goto sysdos

REM ########## SYSTEM WINDOWS ANFANG ##########
:syswin
REM ## UMGEBUNGSVARIABLE ERSTELLEN ##
set datdir=%instdir1%\%instdir2%\%instdir3%
set progdir=%windir%

REM ## DATEIEN UND VERZEICHNISSE ENTFERNEN ##
echo Entferne Dateien:
echo Such.000 - Such.009
echo Such.dbd
del %datdir%\Such.*
echo Liesmich.txt
del %datdir%\*.txt
echo Such.bat
if not exist %progdir%\Such.bat goto datfehlt
del %progdir%\Such.bat

echo Entferne Verzeichnisse, wenn sie leer sind:
echo %instdir1%\%instdir2%\%instdir3%
rd %instdir1%\%instdir2%\%instdir3%
echo %instdir1%\%instdir2%
rd %instdir1%\%instdir2%
echo %instdir1%
rd %instdir1%

echo Zum Fertigstellen der Deinstallation von InKaSuch eine Taste betaetigen.
pause > nul
goto delvar1
REM ########## SYSTEM WINDOWS ENDE ##########

REM ########## SYSTEM DOS ANFANG ##########
:sysdos
REM ## UMGEBUNGSVARIABLE ERSTELLEN ##
set datdir=C:\%instdir2%\%instdir3%
set progdir=C:

REM ## DATEIEN UND VERZEICHNISSE ENTFERNEN ##
echo Entferne Dateien:
echo Such.000 - Such.009
echo Such.dbd
del %datdir%\Such.*
echo Liesmich.txt
del %datdir%\*.txt
echo Such.bat
if not exist %progdir%\Such.bat goto datfehlt
del %progdir%\Such.bat

echo Entferne Verzeichnisse, wenn sie leer sind:
echo C:\%instdir2%\%instdir3%
rd C:\%instdir2%\%instdir3%
echo C:\%instdir2%
rd C:\%instdir2%

echo Zum Fertigstellen der Deinstallation von InKaSuch eine Taste betaetigen.
pause > nul
goto delvar1
REM ########## SYSTEM DOS ENDE ##########

REM ## UMGEBUNGSVARIABLEN ZURUECKSETZEN ##
:delvar1
if ".%param1%" == ".u" goto delunin
set instdir1=
set instdir2=
set instdir3=
set datdir=
goto delunin

REM ## UNINSTALL-PROGRAMM ENTFERNEN ##
:delunin
echo Entferne Datei:
echo IKSuchun.bat
del %progdir%\IKSuchun.bat
goto datfehlt

REM ## FEHLERMELDUNGEN ##
:flschpar
echo Fehler - Falsche Parameterangabe!
echo install-such /? gibt hilfe.
pause
goto ende

:datfehlt
echo Fehler - Datei nicht vorhanden oder falscher Speicherort!
echo Deinstallation unvollstaendig.
pause
goto delvar2

REM ## ENDE UND LOESCHEN DER UMGEBUNGSVARIABLEN ##
:delvar2
set progdir=
set instdir1=
set instdir2=
set instdir3=
set datdir=

:ende